Oluşturuluş tarihi alanı "Date" alan ismininden sonra gelen bir tarih-saat belirtiminden oluşur.

    özgün-tarih       =       "Date:" tarih-saat CRLF

Oluşturuluş tarihi, iletinin tamamlanıp posta teslimat sistemine girmeye hazır olduğu andaki tarih ve saati belirtir. Örneğin, bu zaman, göndericinin uygulama programının "gönder" düğmesine tıkladığı an olabilir. Her durumda, özellikle iletinin aktarıldığı anı taşısın diye tasarlanmamış aksine iletinin oluşturucusu insan veya sistem tarafından aktarılmaya hazır son duruma getildiği anı taşısın diye tasarlanmıştır. (Örneğin, bir ağa bağlı olmayan bir taşınabilir bilgisayar kullanıcısı bir iletiyi teslimat için kuyruğa koyabilir. Oluşturuluş tarihi, kullanıcının ağa bağlandığında iletiyi gönderdiği anı değil, iletinin kuyruğa konduğu anı içermesi için tasarlanmıştır.)

Bir iletinin oluşturucu alanları kimden alanı, gönderici alanı (uygulanabildiğinde) ve isteğe bağlı olan yanıtla alanından oluşur. kimden alanı, "From" alan ismi ile başlayan bir veya daha fazla posta-kutusu belirtiminin virgül ayraçlı bir listesinden oluşur. Eğer kimden alanı pk-listesi içinde birden fazla posta-kutusu belirtimi içeriyorsa, "Sender" alan ismi ile başlayıp tek bir posta-kutusu belirtiminden oluşan gönderici alanının iletide bulunması gerekir *ZORUNLU*. Her durumda, isteğe bağlı olarak, "Reply-To" alan ismi ile başlayan ve bir veya daha fazla adres içeren bir yanıtla alanı bulunabilir *SEÇİMLİK*.

kimden         =       "From:" pk-listesi CRLF

gönderici      =       "Sender:" posta-kutusu CRLF

yanıtla        =       "Reply-To:" adres-listesi CRLF

Oluşturucu başlıkları ileti kaynağının posta kutularını belirtir. "From:" alanı iletinin yazar(lar)ını, yani, ileti yazma sorumluluğu olan sistem veya kişilerin posta kutularını belirtir. "Sender:" alanı iletinin aktarımından sorumlu aracının posta-kutusunu belirtir. Örneğin, bir iletiyi bir şahıs adına sekreteri gönderiyorsa, sekreterin posta-kutusu "Sender:" alanında, asıl yazarının posta-kutusu ise "From:" alanında görünecektir. Eğer iletinin oluşturucusu olarak yazar ve gönderici için tek bir posta-kutusu belirtilebiliyorsa "Sender:" alanı kullanılmamalıdır *ÖNERİ*. Aksi takdirde her iki başlık alanı da bulunmalıdır *ÖNERİ*.

Oluşturucu alanları ayrıca, ileti yanıtlanırken gerekecek bilgiyi de sağlar. "Reply-To:" alanı mevcut olduğunda, iletinin yazarının yanıtların gönderilmesi için tercih ettiği posta kutularını belirtir. "Reply-To:" alanının yokluğunda, yanıtlar, yanıtı yazan başka bir adresi açıkça belirtmedikçe, öntanımlı olarak "From:" alanında belirtilen posta kutularına gönderilmelidir *ÖNERİ*.

Tüm durumlarda, "From:" alanı iletinin yazar(lar)ıyla ilgisi olmayan herhangi bir posta kutusunu içermemelidir *ÖNERİ*. Bir yanıtın hedef adreslerinin oluşturulması ile ilgili daha fazla bilgi için ayrıca, Hedef adres alanları bölümüne de bakınız.

Bir iletinin hedef alanları hepsi aynı biçimde olan üç olası alandan oluşur. "To", "Cc" veya "Bcc" olabilen bir alan ismi ile başlayıp bir veya daha fazla adresin virgül ayraçlı listesini (posta-kutusu veya grup sözdizimi ile) içeren alanlardır.

kime            =       "To:" adres-listesi CRLF

kkopya          =       "Cc:" adres-listesi CRLF

gizkopya        =       "Bcc:" (adres-listesi / [AKBOŞ]) CRLF

Hedef alanları iletinin alıcılarını belirtir. Her hedef alanı bir veya daha fazla adres içerebilir ve her adres iletinin olası alıcısını belirtir. Bu üç alan arasındaki tek fark nasıl kullanıldıkları ile ilgilidir.

"To:" alanı iletinin birinci dereceden alıcılarını içerir.

"Cc:" alanı (buradaki "Cc", daktiloda karbon kağıdı kullanarak iletinin kopyasının oluşturulmasına benzerlikten hareketle karbon kopya karşılığı olarak "Carbon Copy" kısaltmasıdır.) iletinin içeriğiyle doğrudan ilgisi olmayan ama bilgi için bir kopyanın gitmesinin faydalı olacağı adresleri içerir.

"Bcc:" alanı (buradaki "Bcc", gizli kopya anlamında "Blind Carbon Copy" kısaltmasıdır.) adresleri iletinin diğer alıcılarına ifşa edilmeyecek ileti alıcıların adreslerini içerir. "Bcc:" alanının üç kullanım yolu vardır. Birinci durumda, "Bcc:" alanı içeren bir ileti gönderilmeye hazırlanırken, iletinin bir kopyası alıcıların tümüne ("Bcc:" alanında belirtilenler dahil) gönderildiği halde bile "Bcc:" satırı kaldırılır. İkinci durumda, "To:" ve "Cc:" satırlarında belirtilen alıcılara iletinin bir kopyası gönderilirken yukarıdaki gibi "Bcc:" satırı kaldırılır, fakat "Bcc:" satırındaki alıcılar iletinin bir "Bcc:" satırı içeren ayrı bir kopyasını alırlar. ("Bcc:" alanında çok sayıda alıcı belirtildiği durumda bazı gerçeklenimler iletinin her gizli kopya alıcısına "Bcc:" satırında sadece onun adresinin bulunduğu ayrı bir kopya gönderir.) Son olarak, bir "Bcc:" satırı hiçbir adres içermeyebileceğinden (sözdizimsel olarak), gizli kopya alıcılarına hiçbir adres içermeyen "Bcc:" satırlı kopya gönderilir. "Bcc:" alanı için kullanılan yöntem gerçeklenime bağımlıdır, fakat her biri ile ilgili açıklamalar için Güvenlik Değerlendirmeleri bölümüne bakınız.

Bir ileti başka bir iletinin yanıtı olduğunda, özgün iletinin yazarlarının posta kutuları ("From:" alanındaki posta kutuları) veya (eğer varsa) "Reply-To:" alanındaki posta kutuları, bunlar normalde yanıtın birinci dereceden alıcıları olacağı için, yanıtın "To:" alanında bulunabilir *SEÇİMLİK*. Eğer bir ileti, hedef alanlarına sahip bir iletiye yanıt olarak gönderiliyorsa, iletinin yazarından başka alıcılarının tümüne yanıtın bir kopyasının gönderilmesi çoğunlukla istenen birşeydir. Böyle bir yanıt şekillendirilirken, özgün iletinin "To:" ve "Cc:" satırlarındaki adresler, bunlar normalde yanıtın ikinci dereceden alıcıları olduklarından, yanıtın "Cc:" alanında bulunabilir *SEÇİMLİK*. Eğer özgün iletide bir "Bcc:" adresleri varsa, bu adresler yanıtın "Bcc:" alanında bulunabilir *SEÇİMLİK*, fakat "To:" veya "Cc:" alanlarında bulunmamaları gerekir *ÖNERİ*.

İsteğe bağlı olmasına rağmen, her iletinin bir "Message-ID:" alanı olması gerekir *ÖNERİ*. Diğer yandan, yanıt iletilerinin aşağıda açıklandığı gibi uygun düştüğünde "In-Reply-To:" ve "References:" alanlarını da içermesi gerekir *ÖNERİ*.

"Message-ID:" alanı tek bir eşsiz ileti kimliği içerir. "References:" ve "In-Reply-To:" alanlarının her biri bir veya daha fazla sayıda ileti kimliği içerir; bunlar birbirlerinden isteğe bağlı olarak AKBOŞ belirtimi ile ayrılabilir.

İleti kimliği (ilt-id), dahili AKBOŞ belirtimi olmaksızın açılı-adres sözdizimine benzer.

ileti-id      =     "Message-ID:" ilt-id CRLF

ata-id        =     "In-Reply-To:" 1*ilt-id CRLF

atıflar       =     "References:" 1*ilt-id CRLF

ilt-id        =     [AKBOŞ] "<" id-sol "@" id-sağ ">" [AKBOŞ]

id-sol        =     nokta-atom-dizgesi / katsız-tırnak / atıl-id-sol

id-sağ        =     nokta-atom-dizgesi / katsız-sabit / atıl-id-sağ

katsız-tırnak =     ÇTIRNAK *(tdizge / öteli-çift) ÇTIRNAK

katsız-sabit  =     "[" *(ddizgesi / öteli-çift) "]"

"Message-ID:" alanı, belli bir iletinin belli bir sürümüne atıf yapan bir eşsiz ileti kimliği sağlar. İleti kimliğinin eşsizliği onu üreten konak tarafından garanti edilir (aşağıya bakınız). Bu ileti kimliği insanlarca okunabilir olması gerekmeyen makinelerce okunabilen biçimde tasarlanır. Bir ileti kimliği belli bir iletinin sadece tek bir nesnel örneği ile ilgilidir; iletinin sonraki sürümlerinin her biri yeni bir ileti kimliği alır.

"In-Reply-To:" ve "References:" alanları bir iletiye yanıt oluşturulurken kullanılır. Bunlar, özgün iletinin ileti kimliğini ve (örneğin yanıtlanan iletinin kendisinin bir yanıt olduğu durumda) diğer iletilerin ileti kimliklerini de barındırırlar. "In-Reply-To:" alanı yeni iletinin bir yanıtı olduğu iletiyi tanıtmakta kullanılabilirken, "References:" alanı tartışmanın "evrelerini" tanıtmakta kullanılabilir.

Bir iletiye bir yanıt oluşturulurken, sonuçlanacak iletinin "In-Reply-To:" ve "References:" alanları şöyle oluşturulurlar:

"In-Reply-To:" alanı, yanıtı olduğu iletinin ("ata ileti") "Message-ID:" değerini içerecektir. Eğer birden fazla ata ileti varsa, "In-Reply-To:" alanı tüm ata iletilerin "Message-ID:" değerlerini içerecektir. Ata iletilerin hiçbiri "Message-ID:" alanı içermiyorsa, yeni iletide bir "In-Reply-To:" alanı olmayacaktır.

"References:" alanı, ata iletinin (varsa) "References:" değerine ek olarak ata iletinin (varsa) "Message-ID:" değerini içerecektir. Eğer ata iletinin bir "References:" alanı yoksa ama "In-Reply-To:" alanı mevcut ve tek bir ileti kimliği içeriyorsa, "References:" alanı ata iletinin "In-Reply-To:" değerine ek olarak ata iletinin (varsa) "Message-ID:" değerini içerecektir. Eğer ata iletide "References:", "In-Reply-To:" ve "Message-ID:" alanları yoksa, yeni iletinin "References:" diye bir alanı olmayacaktır.

İleti kimliğinin (ilt-id) kendisi o ileti için genel anlamda eşsiz bir kimlik olmalıdır *ZORUNLU*. İleti kimliği üreteci ilt-id'nin eşsizliğini garanti etmelidir. *ZORUNLU* ilt-id sözdizimsel olarak açılı-adrese benzediğinden (açıklamalar va katlama boşlukları atıldığında eşdeğerdir), ileti kimliğini oluşturmanın en iyi yolu, ileti kimliğinin oluşturulduğu konağın alan ismini (veya IP adresli alan sabitini) de-imi karakterinin sağına koyup, soluna da, o anki mutlak tarih ve saate ek olarak sistemde o an için eşsiz olan bir başka kimliği (muhtemelen sıralı bir değer, örneğin, sürecin kimliğini) koymaktır. Tarihin solda, konak alan adının da sağda yeralması zaten eşsizliği sağlayacaktır, çünkü Genel Ağ'da aynı anda aynı konak alan adı ve IP adresine sahip başka bir konak olamaz. Diğer algoritmalar da iş görecek olsa da, bir konak veya benzeri bir alan için bir ileti kimliği üretecek bir üretecin, o alan için eşsiz bir sol taraf üretmesini garanti edeceğinden, sağ tarafın konak alanı kimliğini içermesi tavsiye edilir *ÖNERİ*.

Sözdizimsel olarak açılı ayraç karakterleri ilt-id'nin birer parçası dağildirler; ilt-id bu iki açılı ayraç arasında kalan nesnedir.

Bilgilendirici alanların tamamı isteğe bağlıdır. "Keywords:" alanı, bir veya daha fazla sözcük ve tırnaklı-dizgenin virgül ayraçlı bir listesini içerir. "Subject:" ve "Comments:" alanları ise Yapısız Başlık Alanı Gövdeleri bölümünde bahsedilen yapısız başlık alanlarıdır ve bu nedenle, metin ve katlama boşlukları içerebilirler.

konu          =    "Subject:" yapısız CRLF

açıklamalar   =    "Comments:" yapısız CRLF

anahsözcükler =    "Keywords:" deyim *("," deyim) CRLF

Bu üç alan ileti hakkında sadece insanlarca okunabilecek bilgiler içermesi için tasarlanmıştır. "Subject:" alanı en bilinenidir ve iletinin ana konusunu belirten kısa bir dizge içerir. Bir yanıtta kullanılırken alan içeriği, ata iletinin "Subject:" alanının içeriğinin başına "Re: " (... konusunda/hususunda anlamına gelen Latince "res" sözcüğüne atıf olarak "Re:") konularak elde edilebilir *SEÇİMLİK*. Bu yapılırsa, tek bir tane "Re: " kullanılmalıdır; çünkü, başka dizgelerin eklenmesi veya birden fazla "Re: " bulunması istenmeyen sonuçlara yolaçabilir. "Comments:" alanı, ileti gövdesindeki metin ile ilgili ek açıklamalar içerebilir. "Keywords:" alanı ise, alıcı için yararlı olabilecek önemli sözcük ve deyimlerin virgül ayraçlı bir listesini içerebilir.

Yeniden gönderim alanları, bir kullanıcı bir iletiyi aktarım sistemine yeniden girdiğinde iletiye eklenmelidir *ÖNERİ*. Bunun her yapılışında iletiye ayrı bir yeniden gönderim alanları kümesi eklenmelidir *ÖNERİ*. Yeniden gönderim alanlarının tümü ilgili oldukları yeniden gönderilen ileti ile birlikte olmalıdır *ÖNERİ*. Yeniden gönderim alanlarının her yeni kümesi iletinin daima başlangıcına eklenir; yani, en son yeniden gönderilen ileti daha önceki yeniden gönderim alanlarını da içerir. Yeniden gönderim alanları eklenen bir iletinin diğer alanlarında bir değişiklik yapılmaz.

Yeniden gönderim alanlarının her biri sözdizimindeki başka bir alana karşılıktır. Örneğin, "Resent-Date:" alanı "Date:" alanına, "Resent-To:" alanı da "To:" alanına karşılıktır. Her durumda, alan gövdesinin sözdizimi karşı düştüğü alanın sözdizimi ile aynıdır.

Yeniden gönderim alanları kullanılırken, "Resent-From:" ve "Resent-Date:" alanları mutlaka gönderilmelidir *ZORUNLU*. "Resent-Message-ID:" alanı da gönderilirse iyi olur *ÖNERİ*. "Resent-Sender:" ile "Resent-From:" aynı olacaksa, "Resent-Sender:" kullanılmamalıdır *ÖNERİ*.

yinegönder-tarih     =  "Resent-Date:" tarih-saat CRLF

yinegönder-kimden    =  "Resent-From:" pk-listesi CRLF

yinegönder-gönderici =  "Resent-Sender:" posta-kutusu CRLF

yinegönder-kime      =  "Resent-To:" adres-listesi CRLF

yinegönder-kopya     =  "Resent-Cc:" adres-listesi CRLF

yinegönder-gizkopya  =  "Resent-Bcc:" (adres-listesi / [AKBOŞ]) CRLF

yinegönder-ilt-id    =  "Resent-Message-ID:" ilt-id CRLF

Yeniden gönderim alanları, bir kullanıcı tarafından yeniden aktarım sistemine girilen bir iletiyi tanımlamakta kullanılır. Yeniden gönderim alanlarının kullanım amacı, bu başlıkları içeren iletinin, özgün göndericisi tarafından özgün iletinin başlıkları değişmeksizin tekrar gönderimi olduğunu belirtmektir. Her yeniden gönderim alanları kümesi belli bir yeniden gönderim olayına karşılıktır. Yani, eğer bir ileti birden fazla yeniden gönderim saati içeriyorsa, bunlardan birini içeren her yeniden gönderim alanları kümesi ayrı bir yeniden gönderim olayına karşılıktır. Yeniden gönderim alanları kesinlikle sadece bilgilendiricidir. Bunlar yanıtlama ile ilgili normal işlemlerde veya iletilerle ilgili benzer özdevinimli eylemlerde kullanılmamalıdır *ZORUNLU*.

Yeniden gönderim oluşturucu alanları iletiyi yeniden gönderen kişi ya da sistemin posta kutusunu belirtir. Normal oluşturucu başlıklarındaki gibi iki biçimi vardır: Basit "Resent-From:" türünde alan gövdesi yeniden gönderim yapan bireyin posta kutusunu içerir. Daha karmaşık biçiminde, iletiyi gönderen birey ("Resent-Sender:" alanındaki birey), iletiyi başkalarının ("Resent-From:" alanındaki bireyler) yararına gönderiyordur.

"Resent-Date:" alanı, yeniden gönderilen iletinin, göndericisinin elinden çıktığı tarih ve saati belirtir. Normal "Date:" alanı gibi, iletinin asıl aktarıldığı tarih ve saati göstermez.

"Resent-To:", "Resent-Cc:" ve "Resent-Bcc:" alanlar normal "To:", "Cc:" ve "Bcc:" alanlarına karşılıktır, ancak gövdeleri özgün iletinin alıcılarını değil, yeniden gönderimin alıcılarını içerir.

"Resent-Message-ID:" alanı, yeniden gönderilen iletiye özgü eşsiz kimliği içerir.

İzleme alanları, isteğe bağlı bir "Return-Path:" alanı ile bir veya daha fazla sayıda "Received:" alanından oluşan bir başlık alanları grubudur. "Return-Path:" başlık alanı bir açılı ayraç çifti ile kuşatılmış isteğe bağlı bir adres-belirtimi içerir. "Received:" alanı ise, bir ikinokta imini izleyen bir tarih-saat belirtimi ile biten (boş olması olası) isim/değer çiftlerinden oluşur. İsim/değer çiftlerinin ilk öğesi öğe-ismi ile tanımlanır, ikinci öğesi ise, bir adres-belirtimi, bir atom, bir alan ya da bir ilt-id olabilir. İzleme alanlarının sözdizimine, [RFC2821] gibi, kullanımlarında uygulanmak üzere hazırlanmış standartlara uygun kısıtlamalar uygulanabilir.

izleme          =  [geridönüş] 1*alındı

geridönüş       =  "Return-Path:" yol CRLF

yol             =  ([AKBOŞ] "<" ([AKBOŞ] / adres-belirtimi) ">" [AKBOŞ]) /
                   atıl-yol

alındı          =   "Received:" isim-değer-listesi ";" tarih-saat CRLF

isim-değer-listesi =  [AKBOŞ] [isim-değer-çifti *(AKBOŞ isim-değer-çifti)]

isim-değer-çifti   =  öğe-ismi AKBOŞ öğe-değeri

öğe-ismi           =  HARF *(["-"] (HARF / RAKAM))

öğe-değeri         =  1*açılı-adres / adres-belirtimi /
                        atom / alan / ilt-id

İzleme alanlarının Genel Ağ postasında kullanımı ile ilgili tam açıklama [RFC2821]'de bulunmaktadır. Bu standardın amacı gereği, izleme başlıkları tamamen bilgilendirici olup, bunlarla ilgili biçimsel yorumlama bu standardın kapsamı dışındadır.

İletilerde bu standartta hiç belirtilmemiş alanlar olabilir. Bunlar seçimlik-başlık sözdizimine uymalıdırlar *ZORUNLU*. Böyle bir alan, ":" ve BOŞKRK hariç basılabilir US-ASCII karakterlerinden oluşan bir başlık-alanı-adını izleyen bir ikinokta imini takibeden yapısız biçimli bir metinden oluşur.

Bir seçimlik-başlık alan ismi, bu standartta belirtilen alan isimleniden hiçbiri ile aynı olmamalıdır *ZORUNLU*.

seçimlik-başlık  =    başlık-alanı-adı ":" yapısız CRLF

başlık-alanı-adı =    1*alan-metni

alan-metni       =    %d33-57 /         ; ":", BOŞKRK ve denetim
                      %d59-126          ; karakterleri hariç
                                        ; US-ASCII karakterleri.

Bu standardın amacı gereği isteğe bağlı alanlar yorumsuzdur.