Ek-B. ABNF'nin Çekirdek ABNF'si

Bu bölüm ABNF'nin kendine özgü dilbilgisinin çekirdeğini oluşturan kural tanımlarını içerir. Bu tanımlar çekirdek kural kümesi olarak kullanılabilir. (Buradaki kurallar RFC çevirilerinde kullanılmak üzere Türkçe'ye uyarlanmıştır; İngilizce RFC'lerle ilgili kural tanımları için bu belgenin İngilizce aslına bakınız.)

Çekirdek Kurallar

Belli başlı temel kurallar büyük harflidirler; BOŞ, YSEK, SSSB, RAKAM, HARF gibi.

HARF           =  %x41-5A / %x61-7A   ; A-Z / a-z

BIT            =  "0" / "1"

KRK            =  %x01-7F
                        ; Hiçlik (\0) karakteri hariç
                        ; 7 bitlik bir US-ASCII karakteri

CR             =  %x0D
                        ; satırbaşı karakteri

CRLF           =  CR LF
                        ; Genel Ağ standardı olarak satırsonu

DNT            =  %x00-1F / %x7F
                        ; Denetim karakterleri

RAKAM          =  %x30-39
                        ; 0-9

ÇTIRNAK        =  %x22
                        ; " (Çift tırnak)

RAKAM16        =  RAKAM / "A" / "B" / "C" / "D" / "E" / "F"

YSEK           =  %x09
                        ; yatay sekme karakteri

LF             =  %x0A
                        ; satırsonu karakteri

SÜRBOŞ         =  *(BOŞLUK / CRLF BOŞLUK)
                        ; sürekli (satırsonunu aşan) boşluk

SEKİZLİ        =  %x00-FF
                        ; 8 bitlik veri

BOŞKRK         =  %x20
                        ; boşluk karakteri

GÖRKRK         =  %x21-7E
                        ; görünür (basılabilir) karakterler

BOŞLUK         =  BOŞKRK / YSEK
                        ; boşluklar

Ortak Kodlama

Harici olarak, veri, yüksek sekizinci biti sıfırlanmış sekiz bitlik alanda yedi bitlik US-ASCII olarak tanımlanan ve "ağa göre ASCII" denilen biçimde sunulur. Değer dizgesi, ağa önce gönderilen yüksek değerli baytların solda olduğu "ağ bayt sıralaması"na göre dizilir.